Sommaire :

1- Créez un nouveau fichier action script dans Eclipse

Lancez Eclipse puis: file => new => ActionScript project.

2- Nommez votre projet

Ici ce sera : KeyboardDemo (respectez la casse).

3- Création du script

copiez collez le script suivant :

package {
//imports de packages nécéssaires au fonctionement de la classe
  import flash.display.Sprite;
  import flash.display.Stage;
  import flash.events.Event;
  import flash.events.KeyboardEvent;
  import flash.ui.Keyboard;

  public class KeyboardDemo extends Sprite { 
   
    private var player:Sprite;

    public function KeyboardDemo() {

      player = createAvatar(0x000000) //  on détermine la couleur(noir) de l'objet
      player.x = 200; // sa position sur l'axe x (horizontal)
      player.y = 100; // sa position sur l'axe y (vertical)
      addChild(player);

      stage.addEventListener(KeyboardEvent.KEY_DOWN, keyPressedDown);

    }

    private function keyPressedDown(event:KeyboardEvent):void {
      var key:uint = event.keyCode;
      var step:uint = 5
      switch (key) {
          case Keyboard.LEFT :
            player.x -= step;
            break;
          case Keyboard.RIGHT :
            player.x += step;
            break;
          case Keyboard.UP :
            player.y -= step;
            break;
          case Keyboard.DOWN :
            player.y += step;
            break;
      }
    }

    private function createAvatar(bgColor:uint):Sprite {
      var s:Sprite = new Sprite();
      s.graphics.beginFill(bgColor); 
      s.graphics.drawCircle(0, 0, 40);//création d'un cercle dont on determine la taille
      s.graphics.endFill();
      s.graphics.beginFill(0xff0000);
      s.graphics.drawCircle(-15, -10, 5);// création de l'oeil gauche 
      s.graphics.drawCircle(+15, -10, 5);// création oeil droit
      s.graphics.endFill();
      s.graphics.lineStyle(2, 0xff0000, 100);
      s.graphics.moveTo(-20,15);
        //on définit le point de départ de la courbe
      s.graphics.curveTo(0,35, 20,15); 
        // les deux premiers nombres sont les points de controle de la courbe (soit son inclinaison)
        //les deux derniers, les points finaux de la courbe soit sa longueur)
      return s;
    }
  }
}

4- Cliquez droit sur votre fichier .as

Celui-ci doit logiquement se nommer KeyboardDemo.as et se situer à la racine du projet.

Donc clic droit => Set as default application.

5- Executez votre projet.

 Clic droit sur KeyboardDemo.as => run as => Flex Application.